resource "gitlab_group" "group" {
  name           = var.name
  path           = var.name
  description    = var.description
  parent_id      = var.parent_group != "" ? data.gitlab_group.parent[0].id : null
  default_branch = var.default_branch
  avatar         = local.avatar == null ? null : "${local.avatar}"
  avatar_hash    = local.avatar == null ? null : filesha256("${local.avatar}")
}

resource "gitlab_group_label" "label" {
  for_each = var.labels

  group       = gitlab_group.group.id
  name        = each.key
  description = each.value.description
  color       = each.value.color
}

resource "gitlab_group_badge" "badge" {
  for_each = var.badges

  group     = gitlab_group.group.id
  name      = each.key
  link_url  = each.value.link_url
  image_url = each.value.image_url
}

resource "gitlab_group_variable" "variable" {
  for_each = var.variables

  group             = gitlab_group.group.id
  key               = each.key
  value             = each.value.value
  description       = each.value.description
  protected         = each.value.protected
  masked            = each.value.masked
  environment_scope = each.value.environment_scope
}

resource "gitlab_group_ldap_link" "link_gitlab_group_with_ad_group" {
  for_each = local.permissions_list

  group         = gitlab_group.group.full_path
  cn            = each.value.group
  group_access  = each.value.permission
  ldap_provider = "ldapmain"
}